// BLOCKS / A ephemeral pattern '09.10
// By Tsutomu HIGO  URL: http://www.asahi-net.or.jp/~nj2t-hg/

#version 3.6;
global_settings {
  max_trace_level 5
  assumed_gamma 2.2
  }

camera {
  location <0, -40, 0>
  look_at <0, 0, 0>
  angle 50
  }

light_source {<120, -100, -65> color rgb <0.7, 0.7, 0.5>}

#declare fn_Pigm = function {
  pigment { cells
    turbulence 0.1
    color_map {
      [0   color rgb 1]
      [0.7 color rgb 0]
      }
    scale 3
    }
  }

isosurface {
  function {(y-300*fn_Pigm(x, y, z).gray*0.32/(x*x+z*z+10))*(y+70)+2}
  threshold 25
  max_gradient 100
  contained_by {box {<-30, -15, -20> <30, 3, 20>} }
  texture {
    pigment {color rgbt <1, 0, 0, 0.9>}
    finish {
      ambient 0.3
      diffuse 1
      reflection 0.5
      specular 1
      phong 0.3
      brilliance 1
      }
    }
  scale <1, 1, 1>
  translate x*-3
  no_shadow
  }

#declare Media = media {
  emission 0.05
  intervals 20
  samples 1, 1
  confidence 0.9999
  variance 1/100
  density {
    spherical
    turbulence 0.5
    color_map {
      [0 color rgb <0, 0, 0>]
      [0.1 color rgb <0.1, 0.2, 0.25>]
      [0.5 color rgb <0.5, 0.5, 0.3>]
      [1 color rgb <0.3, 0.4, 0.5>]
      }
    scale 4
    }
  }

union {
  sphere { <0, 20, -10> 90
    pigment { color rgb <0.6, 0.6, 0.6> }
    finish { ambient 0 diffuse 0 }
    interior { media { Media } }
    hollow
    scale 4
    rotate x*60 rotate z*210
    }
  }